adds editors category

modules/editors/default.nix

@@ -0,0 +1,5 @@
+{ config, lib, pkgs, ... }:
+
+{
+  imports = [ ./vim.nix ./emacs.nix ./vscode.nix ];
+}

modules/editors/emacs.nix

@@ -0,0 +1,53 @@
+{ config, lib, pkgs, inputs, ... }:
+
+let
+  emacs = with pkgs;
+    ((emacsPackagesNgGen emacsGcc).emacsWithPackages (epkgs: [ epkgs.vterm ]));
+in {
+  fonts.fonts = [ pkgs.emacs-all-the-icons-fonts ];
+
+  home-manager.users.moritz = {
+    programs.emacs.enable = true;
+    programs.emacs.package = emacs;
+    services.emacs.enable = true;
+    services.emacs.package = emacs;
+
+    home.packages = with pkgs; [
+      ## Emacs itself
+      binutils # native-comp needs 'as', provided by this
+
+      ## Doom dependencies
+      git
+      (ripgrep.override { withPCRE2 = true; })
+      gnutls # for TLS connectivity
+
+      ## Optional dependencies
+      fd # faster projectile indexing
+      imagemagick # for image-dired
+      zstd # for undo-fu-session/undo-tree compression
+
+      ## Module dependencies
+      # :checkers spell
+      # (aspellWithDicts (ds: with ds; [ en en-computers en-science de ]))
+      hunspell
+      hunspellDicts.en_GB-ize
+      hunspellDicts.en_US
+      hunspellDicts.de_DE
+      # :checkers grammar
+      languagetool
+      # :tools lookup & :lang org +roam
+      sqlite
+      # :lang latex & :lang org (latex previews)
+      texlive.combined.scheme-full
+      # :lang nix
+      nixfmt # for formating nix
+      # :lang markdown
+      pandoc
+      # :app everywhere
+      xdotool
+      xorg.xwininfo
+      xclip
+      xorg.xprop
+    ];
+  };
+}

modules/editors/vim.nix

@@ -0,0 +1,9 @@
+{ config, lib, pkgs, ... }:
+
+{
+  home-manager.users.moritz.programs.neovim = {
+    enable = true;
+    vimAlias = true;
+    vimdiffAlias = true;
+  };
+}

modules/editors/vscode.nix

@@ -0,0 +1,22 @@
+{ config, lib, pkgs, ... }:
+
+{
+  home-manager.users.moritz = {
+    programs.vscode = {
+      enable = true;
+      package = pkgs.vscode-fhsWithPackages (ps: with ps; [ git ]);
+      extensions = with pkgs.vscode-extensions;
+        [
+          vscodevim.vim
+          dracula-theme.theme-dracula
+          esbenp.prettier-vscode
+          pkief.material-icon-theme
+        ] ++ pkgs.vscode-utils.extensionsFromVscodeMarketplace [{
+          name = "copilot";
+          publisher = "GitHub";
+          version = "1.7.3689";
+          sha256 = "16zrrymxfymc0039zf48vm22rxjs22mh9zkvkpg45grx2a2m19zh";
+        }];
+    };
+  };
+}